home *** CD-ROM | disk | FTP | other *** search
/ SGI Developer Toolbox 6.1 / SGI Developer Toolbox 6.1 - Disc 4.iso / lib / mathlib / libblas / src_original / ztbmv.f < prev    next >
Encoding:
Text File  |  1994-08-02  |  12.7 KB  |  381 lines
  1. *
  2. ************************************************************************
  3. *
  4.       SUBROUTINE ZTBMV ( UPLO, TRANS, DIAG, N, K, A, LDA, X, INCX )
  5. *     .. Scalar Arguments ..
  6.       INTEGER            INCX, K, LDA, N
  7.       CHARACTER*1        DIAG, TRANS, UPLO
  8. *     .. Array Arguments ..
  9.       COMPLEX*16         A( LDA, * ), X( * )
  10. *     ..
  11. *
  12. *  Purpose
  13. *  =======
  14. *
  15. *  ZTBMV  performs one of the matrix-vector operations
  16. *
  17. *     x := A*x,   or   x := A'*x,   or   x := conjg( A' )*x,
  18. *
  19. *  where x is an n element vector and  A is an n by n unit, or non-unit,
  20. *  upper or lower triangular band matrix, with ( k + 1 ) diagonals.
  21. *
  22. *  Parameters
  23. *  ==========
  24. *
  25. *  UPLO   - CHARACTER*1.
  26. *           On entry, UPLO specifies whether the matrix is an upper or
  27. *           lower triangular matrix as follows:
  28. *
  29. *              UPLO = 'U' or 'u'   A is an upper triangular matrix.
  30. *
  31. *              UPLO = 'L' or 'l'   A is a lower triangular matrix.
  32. *
  33. *           Unchanged on exit.
  34. *
  35. *  TRANS  - CHARACTER*1.
  36. *           On entry, TRANS specifies the operation to be performed as
  37. *           follows:
  38. *
  39. *              TRANS = 'N' or 'n'   x := A*x.
  40. *
  41. *              TRANS = 'T' or 't'   x := A'*x.
  42. *
  43. *              TRANS = 'C' or 'c'   x := conjg( A' )*x.
  44. *
  45. *           Unchanged on exit.
  46. *
  47. *  DIAG   - CHARACTER*1.
  48. *           On entry, DIAG specifies whether or not A is unit
  49. *           triangular as follows:
  50. *
  51. *              DIAG = 'U' or 'u'   A is assumed to be unit triangular.
  52. *
  53. *              DIAG = 'N' or 'n'   A is not assumed to be unit
  54. *                                  triangular.
  55. *
  56. *           Unchanged on exit.
  57. *
  58. *  N      - INTEGER.
  59. *           On entry, N specifies the order of the matrix A.
  60. *           N must be at least zero.
  61. *           Unchanged on exit.
  62. *
  63. *  K      - INTEGER.
  64. *           On entry with UPLO = 'U' or 'u', K specifies the number of
  65. *           super-diagonals of the matrix A.
  66. *           On entry with UPLO = 'L' or 'l', K specifies the number of
  67. *           sub-diagonals of the matrix A.
  68. *           K must satisfy  0 .le. K.
  69. *           Unchanged on exit.
  70. *
  71. *  A      - COMPLEX*16       array of DIMENSION ( LDA, n ).
  72. *           Before entry with UPLO = 'U' or 'u', the leading ( k + 1 )
  73. *           by n part of the array A must contain the upper triangular
  74. *           band part of the matrix of coefficients, supplied column by
  75. *           column, with the leading diagonal of the matrix in row
  76. *           ( k + 1 ) of the array, the first super-diagonal starting at
  77. *           position 2 in row k, and so on. The top left k by k triangle
  78. *           of the array A is not referenced.
  79. *           The following program segment will transfer an upper
  80. *           triangular band matrix from conventional full matrix storage
  81. *           to band storage:
  82. *
  83. *                 DO 20, J = 1, N
  84. *                    M = K + 1 - J
  85. *                    DO 10, I = MAX( 1, J - K ), J
  86. *                       A( M + I, J ) = matrix( I, J )
  87. *              10    CONTINUE
  88. *              20 CONTINUE
  89. *
  90. *           Before entry with UPLO = 'L' or 'l', the leading ( k + 1 )
  91. *           by n part of the array A must contain the lower triangular
  92. *           band part of the matrix of coefficients, supplied column by
  93. *           column, with the leading diagonal of the matrix in row 1 of
  94. *           the array, the first sub-diagonal starting at position 1 in
  95. *           row 2, and so on. The bottom right k by k triangle of the
  96. *           array A is not referenced.
  97. *           The following program segment will transfer a lower
  98. *           triangular band matrix from conventional full matrix storage
  99. *           to band storage:
  100. *
  101. *                 DO 20, J = 1, N
  102. *                    M = 1 - J
  103. *                    DO 10, I = J, MIN( N, J + K )
  104. *                       A( M + I, J ) = matrix( I, J )
  105. *              10    CONTINUE
  106. *              20 CONTINUE
  107. *
  108. *           Note that when DIAG = 'U' or 'u' the elements of the array A
  109. *           corresponding to the diagonal elements of the matrix are not
  110. *           referenced, but are assumed to be unity.
  111. *           Unchanged on exit.
  112. *
  113. *  LDA    - INTEGER.
  114. *           On entry, LDA specifies the first dimension of A as declared
  115. *           in the calling (sub) program. LDA must be at least
  116. *           ( k + 1 ).
  117. *           Unchanged on exit.
  118. *
  119. *  X      - COMPLEX*16       array of dimension at least
  120. *           ( 1 + ( n - 1 )*abs( INCX ) ).
  121. *           Before entry, the incremented array X must contain the n
  122. *           element vector x. On exit, X is overwritten with the
  123. *           tranformed vector x.
  124. *
  125. *  INCX   - INTEGER.
  126. *           On entry, INCX specifies the increment for the elements of
  127. *           X. INCX must not be zero.
  128. *           Unchanged on exit.
  129. *
  130. *
  131. *  Level 2 Blas routine.
  132. *
  133. *  -- Written on 22-October-1986.
  134. *     Jack Dongarra, Argonne National Lab.
  135. *     Jeremy Du Croz, Nag Central Office.
  136. *     Sven Hammarling, Nag Central Office.
  137. *     Richard Hanson, Sandia National Labs.
  138. *
  139. *
  140. *     .. Parameters ..
  141.       COMPLEX*16         ZERO
  142.       PARAMETER        ( ZERO = ( 0.0D+0, 0.0D+0 ) )
  143. *     .. Local Scalars ..
  144.       COMPLEX*16         TEMP
  145.       INTEGER            I, INFO, IX, J, JX, KPLUS1, KX, L
  146.       LOGICAL            NOCONJ, NOUNIT
  147. *     .. External Functions ..
  148.       LOGICAL            LSAME
  149.       EXTERNAL           LSAME
  150. *     .. External Subroutines ..
  151.       EXTERNAL           XERBLA
  152. *     .. Intrinsic Functions ..
  153.       INTRINSIC          DCONJG, MAX, MIN
  154. *     ..
  155. *     .. Executable Statements ..
  156. *
  157. *     Test the input parameters.
  158. *
  159.       INFO = 0
  160.       IF     ( .NOT.LSAME( UPLO , 'U' ).AND.
  161.      $         .NOT.LSAME( UPLO , 'L' )      )THEN
  162.          INFO = 1
  163.       ELSE IF( .NOT.LSAME( TRANS, 'N' ).AND.
  164.      $         .NOT.LSAME( TRANS, 'T' ).AND.
  165.      $         .NOT.LSAME( TRANS, 'C' )      )THEN
  166.          INFO = 2
  167.       ELSE IF( .NOT.LSAME( DIAG , 'U' ).AND.
  168.      $         .NOT.LSAME( DIAG , 'N' )      )THEN
  169.          INFO = 3
  170.       ELSE IF( N.LT.0 )THEN
  171.          INFO = 4
  172.       ELSE IF( K.LT.0 )THEN
  173.          INFO = 5
  174.       ELSE IF( LDA.LT.( K + 1 ) )THEN
  175.          INFO = 7
  176.       ELSE IF( INCX.EQ.0 )THEN
  177.          INFO = 9
  178.       END IF
  179.       IF( INFO.NE.0 )THEN
  180.          CALL XERBLA( 'ZTBMV ', INFO )
  181.          RETURN
  182.       END IF
  183. *
  184. *     Quick return if possible.
  185. *
  186.       IF( N.EQ.0 )
  187.      $   RETURN
  188. *
  189.       NOCONJ = LSAME( TRANS, 'T' )
  190.       NOUNIT = LSAME( DIAG , 'N' )
  191. *
  192. *     Set up the start point in X if the increment is not unity. This
  193. *     will be  ( N - 1 )*INCX   too small for descending loops.
  194. *
  195.       IF( INCX.LE.0 )THEN
  196.          KX = 1 - ( N - 1 )*INCX
  197.       ELSE IF( INCX.NE.1 )THEN
  198.          KX = 1
  199.       END IF
  200. *
  201. *     Start the operations. In this version the elements of A are
  202. *     accessed sequentially with one pass through A.
  203. *
  204.       IF( LSAME( TRANS, 'N' ) )THEN
  205. *
  206. *         Form  x := A*x.
  207. *
  208.          IF( LSAME( UPLO, 'U' ) )THEN
  209.             KPLUS1 = K + 1
  210.             IF( INCX.EQ.1 )THEN
  211.                DO 20, J = 1, N
  212.                   IF( X( J ).NE.ZERO )THEN
  213.                      TEMP = X( J )
  214.                      L    = KPLUS1 - J
  215.                      DO 10, I = MAX( 1, J - K ), J - 1
  216.                         X( I ) = X( I ) + TEMP*A( L + I, J )
  217.    10                CONTINUE
  218.                      IF( NOUNIT )
  219.      $                  X( J ) = X( J )*A( KPLUS1, J )
  220.                   END IF
  221.    20          CONTINUE
  222.             ELSE
  223.                JX = KX
  224.                DO 40, J = 1, N
  225.                   IF( X( JX ).NE.ZERO )THEN
  226.                      TEMP = X( JX )
  227.                      IX   = KX
  228.                      L    = KPLUS1  - J
  229.                      DO 30, I = MAX( 1, J - K ), J - 1
  230.                         X( IX ) = X( IX ) + TEMP*A( L + I, J )
  231.                         IX      = IX      + INCX
  232.    30                CONTINUE
  233.                      IF( NOUNIT )
  234.      $                  X( JX ) = X( JX )*A( KPLUS1, J )
  235.                   END IF
  236.                   JX = JX + INCX
  237.                   IF( J.GT.K )
  238.      $               KX = KX + INCX
  239.    40          CONTINUE
  240.             END IF
  241.          ELSE
  242.             IF( INCX.EQ.1 )THEN
  243.                DO 60, J = N, 1, -1
  244.                   IF( X( J ).NE.ZERO )THEN
  245.                      TEMP = X( J )
  246.                      L    = 1      - J
  247.                      DO 50, I = MIN( N, J + K ), J + 1, -1
  248.                         X( I ) = X( I ) + TEMP*A( L + I, J )
  249.    50                CONTINUE
  250.                      IF( NOUNIT )
  251.      $                  X( J ) = X( J )*A( 1, J )
  252.                   END IF
  253.    60          CONTINUE
  254.             ELSE
  255.                KX = KX + ( N - 1 )*INCX
  256.                JX = KX
  257.                DO 80, J = N, 1, -1
  258.                   IF( X( JX ).NE.ZERO )THEN
  259.                      TEMP = X( JX )
  260.                      IX   = KX
  261.                      L    = 1       - J
  262.                      DO 70, I = MIN( N, J + K ), J + 1, -1
  263.                         X( IX ) = X( IX ) + TEMP*A( L + I, J )
  264.                         IX      = IX      - INCX
  265.    70                CONTINUE
  266.                      IF( NOUNIT )
  267.      $                  X( JX ) = X( JX )*A( 1, J )
  268.                   END IF
  269.                   JX = JX - INCX
  270.                   IF( ( N - J ).GE.K )
  271.      $               KX = KX - INCX
  272.    80          CONTINUE
  273.             END IF
  274.          END IF
  275.       ELSE
  276. *
  277. *        Form  x := A'*x  or  x := conjg( A' )*x.
  278. *
  279.          IF( LSAME( UPLO, 'U' ) )THEN
  280.             KPLUS1 = K + 1
  281.             IF( INCX.EQ.1 )THEN
  282.                DO 110, J = N, 1, -1
  283.                   TEMP = X( J )
  284.                   L    = KPLUS1 - J
  285.                   IF( NOCONJ )THEN
  286.                      IF( NOUNIT )
  287.      $                  TEMP = TEMP*A( KPLUS1, J )
  288.                      DO 90, I = J - 1, MAX( 1, J - K ), -1
  289.                         TEMP = TEMP + A( L + I, J )*X( I )
  290.    90                CONTINUE
  291.                   ELSE
  292.                      IF( NOUNIT )
  293.      $                  TEMP = TEMP*DCONJG( A( KPLUS1, J ) )
  294.                      DO 100, I = J - 1, MAX( 1, J - K ), -1
  295.                         TEMP = TEMP + DCONJG( A( L + I, J ) )*X( I )
  296.   100                CONTINUE
  297.                   END IF
  298.                   X( J ) = TEMP
  299.   110          CONTINUE
  300.             ELSE
  301.                KX = KX + ( N - 1 )*INCX
  302.                JX = KX
  303.                DO 140, J = N, 1, -1
  304.                   TEMP = X( JX )
  305.                   KX   = KX      - INCX
  306.                   IX   = KX
  307.                   L    = KPLUS1  - J
  308.                   IF( NOCONJ )THEN
  309.                      IF( NOUNIT )
  310.      $                  TEMP = TEMP*A( KPLUS1, J )
  311.                      DO 120, I = J - 1, MAX( 1, J - K ), -1
  312.                         TEMP = TEMP + A( L + I, J )*X( IX )
  313.                         IX   = IX   - INCX
  314.   120                CONTINUE
  315.                   ELSE
  316.                      IF( NOUNIT )
  317.      $                  TEMP = TEMP*DCONJG( A( KPLUS1, J ) )
  318.                      DO 130, I = J - 1, MAX( 1, J - K ), -1
  319.                         TEMP = TEMP + DCONJG( A( L + I, J ) )*X( IX )
  320.                         IX   = IX   - INCX
  321.   130                CONTINUE
  322.                   END IF
  323.                   X( JX ) = TEMP
  324.                   JX      = JX   - INCX
  325.   140          CONTINUE
  326.             END IF
  327.          ELSE
  328.             IF( INCX.EQ.1 )THEN
  329.                DO 170, J = 1, N
  330.                   TEMP = X( J )
  331.                   L    = 1      - J
  332.                   IF( NOCONJ )THEN
  333.                      IF( NOUNIT )
  334.      $                  TEMP = TEMP*A( 1, J )
  335.                      DO 150, I = J + 1, MIN( N, J + K )
  336.                         TEMP = TEMP + A( L + I, J )*X( I )
  337.   150                CONTINUE
  338.                   ELSE
  339.                      IF( NOUNIT )
  340.      $                  TEMP = TEMP*DCONJG( A( 1, J ) )
  341.                      DO 160, I = J + 1, MIN( N, J + K )
  342.                         TEMP = TEMP + DCONJG( A( L + I, J ) )*X( I )
  343.   160                CONTINUE
  344.                   END IF
  345.                   X( J ) = TEMP
  346.   170          CONTINUE
  347.             ELSE
  348.                JX = KX
  349.                DO 200, J = 1, N
  350.                   TEMP = X( JX )
  351.                   KX   = KX      + INCX
  352.                   IX   = KX
  353.                   L    = 1       - J
  354.                   IF( NOCONJ )THEN
  355.                      IF( NOUNIT )
  356.      $                  TEMP = TEMP*A( 1, J )
  357.                      DO 180, I = J + 1, MIN( N, J + K )
  358.                         TEMP = TEMP + A( L + I, J )*X( IX )
  359.                         IX   = IX   + INCX
  360.   180                CONTINUE
  361.                   ELSE
  362.                      IF( NOUNIT )
  363.      $                  TEMP = TEMP*DCONJG( A( 1, J ) )
  364.                      DO 190, I = J + 1, MIN( N, J + K )
  365.                         TEMP = TEMP + DCONJG( A( L + I, J ) )*X( IX )
  366.                         IX   = IX   + INCX
  367.   190                CONTINUE
  368.                   END IF
  369.                   X( JX ) = TEMP
  370.                   JX      = JX   + INCX
  371.   200          CONTINUE
  372.             END IF
  373.          END IF
  374.       END IF
  375. *
  376.       RETURN
  377. *
  378. *     End of ZTBMV .
  379. *
  380.       END
  381.